PRELIMINARY COMPARISION OF THE HST AND WHITE DWARF ABSOLUTE FLUX SCALES


              Ralph Bohlin
              Space Telescope Science Institute

              Instrument Science Report on Standard Calibration Sources 002
              December 1993


SUMMARY

As part of an ongoing effort to develop a set of standard stars with accurate
absolute spectrophotometry from 1050 to 10000A, the FOS flux spectrum for
G191B2B (WD0501+527) is divided by a model spectrum for the case of a pure
hydrogen atmosphere to derive the difference between the current HST flux scale
and the flux scale defined by the physics of model atmosphere calculations.
Figure 1 and the Appendix specify the conversion function. 

DISCUSSION

G191B2B is one of four standard stars that are used to establish and routinely 
monitor the FOS sensitivity. Figure 1 shows the ratio of the observed fluxes to
the model for a) the FOS blue side, b) the FOS red side, and c) the composite
reference spectrum of the IUE+Oke that resides in the STScI Calibration Data
Base System (CDBS). These FOS spectra are from the high dispersion modes, which
have a resolving power of ~1200. See Bohlin and Lindler (1992) for details of
the pedigree of the CDBS reference spectra. The pure hydrogen model is for
60,000 K, log g = 7.5 and is normalized to m=11.79 mag at 5490A, where m=0
corresponds to 3.61E-9 in F-lambda units (Finley, private communication). The
dots in the top three panels of Figure 1 a-c are the actual ratios of the
observations/model in 10A bins, while the heavy solid lines are spline fits to
the ratios using 40 spline nodes. The bottom panel d) compares the adopted fit
for the FOS blue side (heavy solid line) with the FOS red (dots) and the CDBS
(dashed line). 

The FOS spectra have been flux calibrated according to the prescription of
Lindler and Bohlin (1994), which will supersede the current pipeline
procedure that is documented in Neill, Bohlin, and Hartig (1992). The main
improvements in the new calibration procedure account for the changing
sensitivity of FOS with time and for the OTA focus changes due to desorption
(Lindler and Bohlin 1993). The agreement in Figure 1d to ~2% typically between
the FOS blue and red side high dispersion fluxes in their overlap region
longward of 1600A is indicative of the internal consistency of the new flux
calibration procedure.  If the 4 coadded FOS blue side observations happened to
be all low by a 2-3 sigma statistical scatter in the repeatability of FOS
spectrophotometry, the systematic difference of ~4% between the FOS blue
correction and the CDBS (i.e. IUE) correction in the 2000-3000A region could be
explained. Alternatively, our IUE reference spectrum of G191B2B (Bohlin, et al.
1990) might be high by up to ~4%, since that flux level is defined by the sum of
only 6 IUE long wavelength (LW) spectra. More study is need to resolve this
small inconsistency. 

The +10% bump in the CDBS correction at 3200A is caused by a mismatch between
the IUE and the Oke (1990) spectra. Since this region of the reference spectrum
is ignored in the fitting process used to derive FOS calibrations, the
residuals of the FOS fluxes with respect to the model are much less. However,
the deviation of the the FOS from the model at 3200-3500A is probably due to the
uncertainties of the Oke reference data. Longward of 3500A, the residuals
illustrate the current uncertainty level of ~3% in the data/model.



The preliminary conversion from the current HST flux scale to the WD flux scale
is accomplished by dividing the current FOS fluxes by the function represented
by the heavy solid line in the bottom panel of Figure 1. The Appendix is an IDL
conversion procedure, which contains the table of the 40 spline nodes that
define this conversion function. 

FUTURE WORK

Without the complications of an intervening atmosphere, more accurate relative
spectrophotometry should be possible with FOS than has been previously achieved
over the wavelength range 1150-8500A. Therefore, the goal of the analysis of the
calibration data is to understand all uncertainties above the 1% level.
Eventually, the adjustment of the IUE-HST absolute flux scale should probably be
converted to the white dwarf flux standard. However, more FOS observations of
white dwarfs with the purest hydrogen atmospheres are needed to derive the
white dwarf based FOS calibration to greater precision. Additional work on the
inclusion of metals in the model atmosphere calculations for G191B2B is needed,
since Sion, et al. (1992) have shown that absorption in metal lines is important
at the ~2% level in some wavelength regions. 

REFERENCES

Bohlin, R. C., Harris, A., Holm, A., and Gry, C. 1990, Ap. J. Suppl., 73, 413.

Bohlin, R. C., & Lindler, D. J. 1992, Instrument Science Report CAL/SCS-001.

Lindler, D. J., & Bohlin, R. C. 1993, FOS Instrument Science Report CAL/FOS-102.

Lindler, D. J., & Bohlin, R. C. 1994, FOS Instrument Science Report CAL/FOS-in
      preparation.

Neill, J. D., Bohlin, R. C., & Hartig, G. 1992, FOS Instrument Science Report
CAL/FOS-077.

Oke, J. B. 1990, Astron. J., 99, 1621.

Sion, E., Bohlin, R., Tweedy, R., and Vauclair, G. 1992, Ap. J. Lett., 391, L29.


APPENDIX

FUNCTION FLXCOR,WAVE,FLX
;+
;
; PURPOSE:
;	CORRECT UV FLUXES TO THE WD SCALE IN THE 1150-4400A RANGE. THESE 
;	PRELIMINARY CORRECTIONS ARE BASED ON FOS HI-DISP BLUE OBS AND FINLEY 
;	MODEL FOR G191B2B ONLY.  rcb
;
;calling sequence:
;	CORRECTED_FLUX=FLXCOR(WAVE,FLX)
;
; input: WAVE-WAVELENGTH ARRAY OF FLUX VECTOR TO BE CORRECTED
;	 FLX-CORRESPONDING FLUX VECTOR TO BE CORRECTED
; output-THE FLX SPECTRUM CONVERTED TO THE WD STANDARD SPECTROPHOTOMETRY SCALE.
;
; HISTORY:
;	93DEC8-RCB
;	93DEC14-UPDATE SPLINE NODES
;-
; TABLE OF x spline nodes for g191b2b blue fos hi-disp
WFIT=[									$
1168.0,1250.8,1333.6,1416.5,1499.3,1582.1,1664.9,1747.7,1830.6,1913.4,	$
1996.2,2079.0,2161.8,2244.7,2327.5,2410.3,2493.1,2575.9,2658.8,2741.6,	$
2824.4,2907.2,2990.1,3072.9,3155.7,3238.5,3321.3,3404.2,3487.0,3569.8,	$
3652.6,3735.4,3818.3,3901.1,3983.9,4066.7,4149.5,4232.4,4315.2,4398.0]

; TABLE OF y spline nodes for g191b2b blue fos hi-disp
CFIT=[									$
1.0616,1.0074,0.9473,0.8713,0.9547,0.8905,0.8843,0.9117,0.9121,0.8852,	$
0.9250,0.9507,0.9369,0.9219,0.9443,0.9653,0.9745,0.9596,0.9675,0.9607,	$
0.9507,0.9654,0.9754,0.9782,0.9893,1.0024,1.0322,1.0299,1.0255,1.0081,	$
0.9979,0.9882,0.9954,1.0198,1.0222,1.0186,1.0157,1.0215,1.0200,1.    ]

GOOD=WHERE((WAVE GE 1150) AND (WAVE LE 4400))
CORRFLUX=FLX
CORRFLUX(GOOD)=FLX(good)/CSPLINE(WFIT,CFIT,WAVE(GOOD))

RETURN,CORRFLUX
END

	FUNCTION CSPLINE,XX,YY,TT
;+
;
;*NAME:		CSPLINE
;
;*PURPOSE:
; function to evaluate a cubic spline at specified data points
;
;*CALLING SEQUENCE:
;	result=cspline(x,y,t)
;
;*PARAMETERS:
; INPUTS:
;	x - vector of spline node positions
;	y - vector of node values
;	t - x-positions to evaluate the spline at
;
; OUTPUT:
;	the values for positions t are returned as the fuction value
;                               
; METHOD:
;	NUMERICAL RECIPES - natural cubic spline is used.
;
; HISTORY:
;	version 1  D. Lindler  May, 1989
;       Mar 16 1991      JKF/ACC    - forced doubleword to avoid
;					integer overflow errors.
;	version 2  D. Lindler  Dec, 1991	- moved to IDL V2.
;	version 3 JKF/ACC	28-jan-1992 - handle not found case of WHERE
;-
;--------------------------------------------------------------------------
;
	x= double(xx)
	y= double(yy)
	t= double(tt)

	n=n_elements(x)
	y2=dblarr(n)		;vector of 2nd direvatives at nodes in xtab
	u=dblarr(n)
;
; decomposition loop of tridiagonal algorithm
;
	for i=1,n-2 do begin
		sig=(x(i)-x(i-1))/(x(i+1)-x(i-1))
		p=sig*y2(i-1)+2.
		y2(i)=(sig-1.0)/p
		u(i)=(6.0*((y(i+1)-y(i))/(x(i+1)-x(i))-(y(i)-y(i-1))/$
			(x(i)-x(i-1)))/(x(i+1)-x(i-1))-sig*u(i-1))/p
	end
;
; backsubstitution
;
	for i=n-2,0,-1 do y2(i)=y2(i)*y2(i+1)+u(i)
;
; find locations of t in xtab using bisection
;
	m=n_elements(t)
	klo=lonarr(m)
	khi=replicate(n-1,m)



bisect:
	not_done=((khi-klo) gt 1)
	if max(not_done) gt 0 then begin
		k=(khi+klo)/2
		higher=x(k) gt t
		sub=where(not_done and higher, sub_found)
		if sub_found gt 0 then khi(sub)=k(sub)
		sub=where(not_done and (not higher), sub_found)
		if sub_found gt 0 then klo(sub)=k(sub)
		goto,bisect
	endif
;
; x(klo) and x(khi) now bracket t
;
	xhi=x(khi)
	xlo=x(klo)
	h=xhi-xlo
	a=(xhi-t)/h
	b=(t-xlo)/h
	return,a*y(klo)+b*y(khi)+((a^3-a)*y2(klo)+(b^3-b)*y2(khi))*(h^2)/6.0
	end